MinimalBible/app/build.gradle

buildscript {
    repositories {
        mavenCentral()

    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-android-extensions:$kotlin_version"
        classpath 'com.github.triplet.gradle:play-publisher:1.0.2'
    }
}

repositories {
    maven {
        url "http://repository.jetbrains.com/all"
    }
}

apply plugin: 'com.android.application'
apply plugin: 'kotlin-android'
apply plugin: 'play'

android {
    compileSdkVersion 22
    buildToolsVersion '21.1.2'
    defaultConfig {
        applicationId 'org.bspeice.minimalbible'
        minSdkVersion 8
        targetSdkVersion 22

        def travis_code = System.getenv("TRAVIS_BUILD_NUMBER")
        if (travis_code)
            versionCode travis_code.toInteger()
        else
            versionCode 0
        versionName '0.7'
    }
    packagingOptions {
        exclude 'META-INF/LICENSE.txt'
        exclude 'META-INF/NOTICE.txt'
        exclude 'META-INF/DEPENDENCIES'
        exclude 'META-INF/LICENSE'
        exclude 'META-INF/NOTICE'
        exclude 'LICENSE.txt'
        exclude 'META-INF/INDEX.LIST'
        exclude 'LICENSE'
        exclude 'NOTICE'
        exclude 'asm-license.txt'
    }
    signingConfigs {
        release {
            storeFile file('src/main/play/MinimalBible.jks')
            storePassword System.getenv("KEYSTORE_PASSWORD")
            keyAlias 'minimalbible signing key'
            keyPassword System.getenv("KEYSTORE_PASSWORD")
        }
    }
    buildTypes {
        release {
            signingConfig signingConfigs.release
        }
    }
    sourceSets {
        main.java.srcDirs += 'src/main/kotlin'
        test.java.srcDirs += 'src/test/kotlin'
    }
}

play {
    serviceAccountEmail = System.getenv("SERVICE_ACCOUNT_EMAIL")
    pk12File = file('src/main/play/play_api.p12')
}

dependencies {
    compile project(':jsword-minimalbible')

    compile 'com.squareup.dagger:dagger:+'
    provided 'com.squareup.dagger:dagger-compiler:+'

    compile 'de.devland.esperandro:esperandro-api:+'
    provided 'de.devland.esperandro:esperandro:+'
    compile 'com.jakewharton:butterknife:+'
    compile 'com.readystatesoftware.systembartint:systembartint:+'
    compile 'com.netflix.rxjava:rxjava-android:+'
    compile 'com.android.support:appcompat-v7:+'
    compile 'com.android.support:recyclerview-v7:+'
    compile 'com.android.support:cardview-v7:+'
    compile 'org.apache.commons:commons-lang3:+'
    compile 'com.orhanobut:logger:+'
    compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"

    // Instrumentation Test dependencies
    androidTestCompile 'com.jayway.awaitility:awaitility:+'
    androidTestCompile 'org.mockito:mockito-core:+'

    // Unit Test dependencies
    testCompile 'junit:junit:4.12'
    testCompile 'com.jayway.awaitility:awaitility:+'
    testCompile 'org.mockito:mockito-core:+'
    testCompile 'org.jetbrains.spek:spek:+'

    // Email debug reports if I crash...
    debugCompile('ch.acra:acra:+') {
        exclude module: 'json'
    }
}