Apophysis-AV/Variations/varHypertile3D2.pas

{
     Apophysis Copyright (C) 2001-2004 Mark Townsend
     Apophysis Copyright (C) 2005-2006 Ronald Hordijk, Piotr Borys, Peter Sdobnov
     Apophysis Copyright (C) 2007-2008 Piotr Borys, Peter Sdobnov
     
     Apophysis "3D hack" Copyright (C) 2007-2008 Peter Sdobnov
     Apophysis "7X" Copyright (C) 2009-2010 Georg Kiehne
     Apophysis AV "Phoenix Edition" Copyright (C) 2021 Alice V. Koryagina

     This program is free software; you can redistribute it and/or modify
     it under the terms of the GNU General Public License as published by
     the Free Software Foundation; either version 2 of the License, or
     (at your option) any later version.

     This program is distributed in the hope that it will be useful,
     but WITHOUT ANY WARRANTY; without even the implied warranty of
     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
     GNU General Public License for more details.

     You should have received a copy of the GNU General Public License
     along with this program; if not, write to the Free Software
     Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
}

unit varHypertile3D2;

interface

uses
  BaseVariation, XFormMan;

type
  TVariationHypertile3D2 = class(TBaseVariation)
  private
    hypertile3D2_p, hypertile3D2_q: integer;
	pa, cx, c2, c2x, s2x, s2y, s2z: double;
  public
    constructor Create;

    class function GetName: string; override;
    class function GetInstance: TBaseVariation; override;

    function GetNrVariables: integer; override;
    function GetVariableNameAt(const Index: integer): string; override;

    function SetVariable(const Name: string; var value: double): boolean; override;
    function GetVariable(const Name: string; var value: double): boolean; override;
    function ResetVariable(const Name: string): boolean; override;

	  procedure Prepare; override;
    procedure CalcFunction; override;
  end;

implementation

uses
  Math;

///////////////////////////////////////////////////////////////////////////////
procedure TVariationHypertile3D2.Prepare;
var 	
	t, qa, r: double;
begin
	pa := PI2 / hypertile3D2_p;
	qa := PI2 / hypertile3D2_q;
	t := cos(pa);
	r := -(t - 1) / (t + cos(qa));
	if (r > 0) then
        r := 1 / sqrt(1 + r)
    else
        r := 1;

	cx := r;	
    c2 := sqr(cx);
    c2x := 2 * cx;

    s2x := 1 + c2;
    s2y := 1 - c2;
	s2z := 1 - c2;
end;

procedure TVariationHypertile3D2.CalcFunction;
var 	
	r2, sina, cosa, x2cx, x, y, vr: double;
begin
  r2 := sqr(FTx^) + sqr(FTy^) + sqr(FTz^);
  
  x2cx := c2x * FTx^;
  x := FTx^ * s2x - cx * (-r2 - 1);
  y := FTy^ * s2y;
  
  vr := vvar / (c2 * r2 + x2cx + 1); 
  SinCos(random(32767) * pa, sina, cosa);
 
  FPx^ := FPx^ + vr * (x * cosa + y * sina);
  FPy^ := FPy^ + vr * (y * cosa - x * sina);
  FPz^ := FPz^ + vr * (FTz^ * s2z);
end;

///////////////////////////////////////////////////////////////////////////////
constructor TVariationHypertile3D2.Create;
begin
  hypertile3D2_p := 3; 
  hypertile3D2_q := 7;
end;

///////////////////////////////////////////////////////////////////////////////
class function TVariationHypertile3D2.GetInstance: TBaseVariation;
begin
  Result := TVariationHypertile3D2.Create;
end;

///////////////////////////////////////////////////////////////////////////////
class function TVariationHypertile3D2.GetName: string;
begin
  Result := 'hypertile3D2';
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationHypertile3D2.GetVariableNameAt(const Index: integer): string;
begin
  case Index Of
  0: Result := 'hypertile3D2_p';
  1: Result := 'hypertile3D2_q';
  else
    Result := '';
  end
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationHypertile3D2.SetVariable(const Name: string; var value: double): boolean;
begin
  Result := False;
  if Name = 'hypertile3D2_p' then begin
    if Value < 3 then Value := 3;
	hypertile3D2_p := Round(Value);
    Result := True;
  end else if Name = 'hypertile3D2_q' then begin
    if Value < 3 then Value := 3;
    hypertile3D2_q := Round(Value);
    Result := True;
  end;
end;

function TVariationHypertile3D2.ResetVariable(const Name: string): boolean;
begin
  Result := False;
  if Name = 'hypertile3D2_p' then begin
    hypertile3D2_p := 3;
    Result := True;
  end else if Name = 'hypertile3D2_q' then begin
    hypertile3D2_q := 7;
    Result := True;
  end;
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationHypertile3D2.GetNrVariables: integer;
begin
  Result := 2;
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationHypertile3D2.GetVariable(const Name: string; var value: double): boolean;
begin
  Result := False;
  if Name = 'hypertile3D2_p' then begin
    Value := hypertile3D2_p;
    Result := True;
  end else if Name = 'hypertile3D2_q' then begin
    Value := hypertile3D2_q;
    Result := True;
  end;
end;

///////////////////////////////////////////////////////////////////////////////
initialization
  RegisterVariation(TVariationClassLoader.Create(TVariationHypertile3D2), true, false);
end.