Apophysis-AV/Variations/varFlux.pas

{
     Apophysis Copyright (C) 2001-2004 Mark Townsend
     Apophysis Copyright (C) 2005-2006 Ronald Hordijk, Piotr Borys, Peter Sdobnov
     Apophysis Copyright (C) 2007-2008 Piotr Borys, Peter Sdobnov
     
     Apophysis "3D hack" Copyright (C) 2007-2008 Peter Sdobnov
     Apophysis "7X" Copyright (C) 2009-2010 Georg Kiehne
     Apophysis AV "Phoenix Edition" Copyright (C) 2021 Alice V. Koryagina

     This program is free software; you can redistribute it and/or modify
     it under the terms of the GNU General Public License as published by
     the Free Software Foundation; either version 2 of the License, or
     (at your option) any later version.

     This program is distributed in the hope that it will be useful,
     but WITHOUT ANY WARRANTY; without even the implied warranty of
     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
     GNU General Public License for more details.

     You should have received a copy of the GNU General Public License
     along with this program; if not, write to the Free Software
     Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
}

unit varFlux;

interface

uses
  BaseVariation, XFormMan;

type
  TVariationFlux = class(TBaseVariation)
  private
	spread, spr: double;
  public
    constructor Create;

    class function GetName: string; override;
    class function GetInstance: TBaseVariation; override;

    function GetNrVariables: integer; override;
    function GetVariableNameAt(const Index: integer): string; override;

    function SetVariable(const Name: string; var value: double): boolean; override;
    function GetVariable(const Name: string; var value: double): boolean; override;

    procedure Prepare; override;
	procedure CalcFunction; override;
  end;

implementation

uses
  Math;

///////////////////////////////////////////////////////////////////////////////
procedure TVariationFlux.Prepare;
begin
	spr := 2 + spread;
end;

///////////////////////////////////////
procedure TVariationFlux.CalcFunction;
var
	avgr, avga, xmv, xpv, frc,
	x, y, y2, s, c: double;
  
begin
	// Avoid reduant calculations by precalculating everything what is used at least twice
	x := FTx^; 
	xpv := x + VVAR; 
    xmv := x - VVAR;
    y := FTy^;	
	y2 := sqr(y);
	
	// We have a division by zero problem in the original flux
	// (What if y + (x-vvar) == 0 ????)
	frc := sqrt(y2 + sqr(xmv));
	if (frc = 0) then frc := 1.0;
	
	avgr := VVAR * (spr * sqrt(sqrt(y2 + sqr(xpv) ) / frc));
	avga := (arctan2(y, xmv) - arctan2(y, xpv)) / 2.0;
	SinCos(avga, s, c);

	FPx^ := FPx^ + avgr * c;
	FPy^ := FPy^ + avgr * s;
	FPz^ := FPz^ + vvar * FTz^;
end;

///////////////////////////////////////////////////////////////////////////////
constructor TVariationFlux.Create;
begin
	spread := 0;
end;

///////////////////////////////////////////////////////////////////////////////
class function TVariationFlux.GetInstance: TBaseVariation;
begin
  Result := TVariationFlux.Create;
end;

///////////////////////////////////////////////////////////////////////////////
class function TVariationFlux.GetName: string;
begin
  Result := 'flux';
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationFlux.GetVariableNameAt(const Index: integer): string;
begin
  case Index Of
	0: Result := 'flux_spread';
  else
    Result := '';
  end
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationFlux.SetVariable(const Name: string; var value: double): boolean;
begin
  Result := False;
  if Name = 'flux_spread' then begin
    spread := Value;
    Result := True;
  end;  
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationFlux.GetNrVariables: integer;
begin
  Result := 1
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationFlux.GetVariable(const Name: string; var value: double): boolean;
begin
   Result := False;
   if Name = 'flux_spread' then begin
    Value := spread;
    Result := True;
  end;  
end;

///////////////////////////////////////////////////////////////////////////////
initialization
  RegisterVariation(TVariationClassLoader.Create(TVariationFlux), true, false);
end.