{
     Apophysis Copyright (C) 2001-2004 Mark Townsend
     Apophysis Copyright (C) 2005-2006 Ronald Hordijk, Piotr Borys, Peter Sdobnov
     Apophysis Copyright (C) 2007-2008 Piotr Borys, Peter Sdobnov
     
     Apophysis "3D hack" Copyright (C) 2007-2008 Peter Sdobnov
     Apophysis "7X" Copyright (C) 2009-2010 Georg Kiehne
     Apophysis AV "Phoenix Edition" Copyright (C) 2021 Alice V. Koryagina

     This program is free software; you can redistribute it and/or modify
     it under the terms of the GNU General Public License as published by
     the Free Software Foundation; either version 2 of the License, or
     (at your option) any later version.

     This program is distributed in the hope that it will be useful,
     but WITHOUT ANY WARRANTY; without even the implied warranty of
     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
     GNU General Public License for more details.

     You should have received a copy of the GNU General Public License
     along with this program; if not, write to the Free Software
     Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
}

unit varLoonie;

interface

uses
  BaseVariation, XFormMan;

type
  TVariationLoonie = class(TBaseVariation)
  private
    sqrvar: double;
    use3D: byte;
    procedure Calc3D;
  public
    constructor Create;

    class function GetName: string; override;
    class function GetInstance: TBaseVariation; override;

    function GetNrVariables: integer; override;
    function GetVariableNameAt(const Index: integer): string; override;

    function SetVariable(const Name: string; var value: double): boolean; override;
    function GetVariable(const Name: string; var value: double): boolean; override;

	  procedure Prepare; override;
    procedure GetCalcFunction(var f: TCalcFunction); override;
    procedure CalcFunction; override;
  end;

implementation

uses
  Math;

///////////////////////////////////////////////////////////////////////////////
procedure TVariationLoonie.Prepare;
begin
  sqrvar := VVAR * VVAR;
end;

procedure TVariationLoonie.GetCalcFunction(var f: TCalcFunction);
begin
  if use3D <> 0 then
    f := Calc3D
  else f := CalcFunction;
end;

///////////////////////////////////////////
procedure TVariationLoonie.CalcFunction;
var r, r2 : double;
begin
  r2 := sqr(FTx^) + sqr(FTy^);

	if (r2 < (sqrvar)) and (r2 <> 0) then
	begin
		r := VVAR * sqrt((sqrvar) / r2 - 1.0);
		FPx^ := FPx^ + r * FTx^;
		FPy^ := FPy^ + r * FTy^;
	end else begin
		FPx^ := FPx^ + VVAR * FTx^;
		FPy^ := FPy^ + VVAR * FTy^;
	end;

  FPz^ := FPz^ + vvar * FTz^;
end;

procedure TVariationLoonie.Calc3D;
var r, r2 : double;
begin
  r2 := sqr(FTx^) + sqr(FTy^) + sqr(FTz^);

	if (r2 < (sqrvar)) and (r2 <> 0) then
	begin
		r := VVAR * sqrt((sqrvar) / r2 - 1.0);
		FPx^ := FPx^ + r * FTx^;
		FPy^ := FPy^ + r * FTy^;
		FPz^ := FPz^ + r * FTz^;
	end else begin
		FPx^ := FPx^ + VVAR * FTx^;
		FPy^ := FPy^ + VVAR * FTy^;
    FPz^ := FPz^ + vvar * FTz^;
	end;
end;

///////////////////////////////////////////////////////////////////////////////
constructor TVariationLoonie.Create;
begin
  sqrvar := 0;
  use3D := 0;
end;

///////////////////////////////////////////////////////////////////////////////
class function TVariationLoonie.GetInstance: TBaseVariation;
begin
  Result := TVariationLoonie.Create;
end;

///////////////////////////////////////////////////////////////////////////////
class function TVariationLoonie.GetName: string;
begin
  Result := 'loonie';
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationLoonie.GetVariableNameAt(const Index: integer): string;
begin
  case Index Of
    0: Result := 'loonie_use3D';
    else
      Result := '';
  end;
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationLoonie.SetVariable(const Name: string; var value: double): boolean;
begin
  Result := False;
  if Name = 'loonie_use3D' then begin
    if Value < 0 then Value := 0;
    if Value > 1 then Value := 1;
    use3D := Round(Value);
    Result := True;
  end;
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationLoonie.GetNrVariables: integer;
begin
  Result := 1;
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationLoonie.GetVariable(const Name: string; var value: double): boolean;
begin
  Result := False;
  if Name = 'loonie_use3D' then begin
    Value := use3D;
    Result := True;
  end;
end;

///////////////////////////////////////////////////////////////////////////////
initialization
  RegisterVariation(TVariationClassLoader.Create(TVariationLoonie), true, false);
end.