{
     Apophysis Copyright (C) 2001-2004 Mark Townsend
     Apophysis Copyright (C) 2005-2006 Ronald Hordijk, Piotr Borys, Peter Sdobnov
     Apophysis Copyright (C) 2007-2008 Piotr Borys, Peter Sdobnov
     
     Apophysis "3D hack" Copyright (C) 2007-2008 Peter Sdobnov
     Apophysis "7X" Copyright (C) 2009-2010 Georg Kiehne

     This program is free software; you can redistribute it and/or modify
     it under the terms of the GNU General Public License as published by
     the Free Software Foundation; either version 2 of the License, or
     (at your option) any later version.

     This program is distributed in the hope that it will be useful,
     but WITHOUT ANY WARRANTY; without even the implied warranty of
     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
     GNU General Public License for more details.

     You should have received a copy of the GNU General Public License
     along with this program; if not, write to the Free Software
     Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
}

unit varSinusoidal;

interface

uses
  BaseVariation, XFormMan;

{$ifdef CPUX86}
  {$define _ASM_}
{$endif}

type
  TVariationSinusoidal = class(TBaseVariation)
  private
	  use3D: byte;
	  procedure CalcFlat;
  public
    constructor Create;

    class function GetName: string; override;
    class function GetInstance: TBaseVariation; override;

    function GetNrVariables: integer; override;
    function GetVariableNameAt(const Index: integer): string; override;

    function SetVariable(const Name: string; var value: double): boolean; override;
    function GetVariable(const Name: string; var value: double): boolean; override;
    
    procedure CalcFunction; override;
	  procedure GetCalcFunction(var f: TCalcFunction); override;
  end;

implementation

uses
  Math;

{ TVariationSinusoidal }

///////////////////////////////////////////////////////////////////////////////
procedure TVariationSinusoidal.GetCalcFunction(var f: TCalcFunction);
begin
	if use3D = 0 then
		f := CalcFlat
	else f := CalcFunction;	
end;

procedure TVariationSinusoidal.CalcFlat;
{$ifndef _ASM_}
begin
  FPx^ := FPx^ + vvar * sin(FTx^);
  FPy^ := FPy^ + vvar * sin(FTy^);
{$else}  
asm  
    fld     qword ptr [eax + vvar]
    mov     edx, [eax + FTx]
    fld     qword ptr [edx]      // FTx
    fsin
    fmul    st, st(1)
	  fadd    qword ptr [edx + 16]  // FPx
    fstp    qword ptr [edx + 16]

    fld     qword ptr [edx + 8]  // FTy
    fsin
    fmulp
	  fadd    qword ptr [edx + 24]  // FPy
    fstp    qword ptr [edx + 24]

    fwait
{$endif}  
end;

procedure TVariationSinusoidal.CalcFunction;
{$ifndef _ASM_}
begin
  FPx^ := FPx^ + vvar * sin(FTx^);
  FPy^ := FPy^ + vvar * sin(FTy^);
  FPz^ := FPz^ + vvar * sin(FTz^);  // AV: changed from linear scale
{$else}  
asm    // AV: added inline asm code
    fld     qword ptr [eax + vvar]
    mov     edx, [eax + FTx]
    fld     qword ptr [edx]      // FTx
    fsin
    fmul    st, st(1)
	  fadd    qword ptr [edx + 16] // FPx
    fstp    qword ptr [edx + 16]

    fld     qword ptr [edx + 8]  // FTy
    fsin
    fmul    st, st(1)
	  fadd    qword ptr [edx + 24]  // FPy
    fstp    qword ptr [edx + 24]
	
	  fld    qword ptr [edx + 32] // FTz
    fsin
    fmulp
	  fadd    qword ptr [edx + 40] // FPz
    fstp    qword ptr [edx + 40]

    fwait
{$endif}  
end;

///////////////////////////////////////////////////////////////////////////////
constructor TVariationSinusoidal.Create;
begin
	use3D := 0;
end;

///////////////////////////////////////////////////////////////////////////////
class function TVariationSinusoidal.GetInstance: TBaseVariation;
begin
  Result := TVariationSinusoidal.Create;
end;

///////////////////////////////////////////////////////////////////////////////
class function TVariationSinusoidal.GetName: string;
begin
  Result := 'sinusoidal';
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationSinusoidal.GetVariableNameAt(const Index: integer): string;
begin
  case Index of
  0: Result := 'sinusoidal_use3D';
  else
    Result := '';
  end; 
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationSinusoidal.SetVariable(const Name: string; var value: double): boolean;
begin
  Result := False;
  if Name = 'sinusoidal_use3D' then begin
    if (Value > 1) then Value := 1;
    if (Value < 0) then Value := 0;
    use3D := Round(Value);
    Result := True;
  end;
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationSinusoidal.GetNrVariables: integer;
begin
  Result := 1;
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationSinusoidal.GetVariable(const Name: string; var value: double): boolean;
begin
  Result := False;
  if Name = 'sinusoidal_use3D' then begin
    Value := use3D;
    Result := True;
  end;
end;

///////////////////////////////////////////////////////////////////////////////
initialization
  RegisterVariation(TVariationClassLoader.Create(TVariationSinusoidal), true, false);
end.
