{
     Apophysis Copyright (C) 2001-2004 Mark Townsend
     Apophysis Copyright (C) 2005-2006 Ronald Hordijk, Piotr Borys, Peter Sdobnov
     Apophysis Copyright (C) 2007-2008 Piotr Borys, Peter Sdobnov
     
     Apophysis "3D hack" Copyright (C) 2007-2008 Peter Sdobnov
     Apophysis "7X" Copyright (C) 2009-2010 Georg Kiehne
     Apophysis AV "Phoenix Edition" Copyright (C) 2021 Alice V. Koryagina

     This program is free software; you can redistribute it and/or modify
     it under the terms of the GNU General Public License as published by
     the Free Software Foundation; either version 2 of the License, or
     (at your option) any later version.

     This program is distributed in the hope that it will be useful,
     but WITHOUT ANY WARRANTY; without even the implied warranty of
     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
     GNU General Public License for more details.

     You should have received a copy of the GNU General Public License
     along with this program; if not, write to the Free Software
     Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
}

unit varPreSinusoidal;

interface

uses
  BaseVariation, XFormMan;

{$ifdef CPUX86}
  {$define _ASM_}
{$endif}

type
  TVariationPreSinusoidal = class(TBaseVariation)
  private
	  use3D: byte;
	  procedure CalcFlat;
  public
    constructor Create;

    class function GetName: string; override;
    class function GetInstance: TBaseVariation; override;

    function GetNrVariables: integer; override;
    function GetVariableNameAt(const Index: integer): string; override;

    function SetVariable(const Name: string; var value: double): boolean; override;
    function GetVariable(const Name: string; var value: double): boolean; override;
    
    procedure CalcFunction; override;
	procedure GetCalcFunction(var f: TCalcFunction); override;
  end;

implementation

uses
  Math;

{ TVariationPreSinusoidal }

///////////////////////////////////////////////////////////////////////////////
procedure TVariationPreSinusoidal.GetCalcFunction(var f: TCalcFunction);
begin
	if use3D = 0 then
		f := CalcFlat
	else f := CalcFunction;	
end;

procedure TVariationPreSinusoidal.CalcFlat;
{$ifndef _ASM_}
begin
  FTx^ := vvar * sin(FTx^);
  FTy^ := vvar * sin(FTy^);
{$else}  
asm    // AV: added inline asm code
    fld     qword ptr [eax + vvar]
    mov     edx, [eax + FTx]
    fld     qword ptr [edx]      // FTx
    fsin
    fmul    st, st(1)
    fstp    qword ptr [edx]

    fld     qword ptr [edx + 8]  // FTy
    fsin
    fmulp
    fstp    qword ptr [edx + 8]

    fwait
{$endif}  
end;

procedure TVariationPreSinusoidal.CalcFunction;
{$ifndef _ASM_}
begin
  FTx^ := vvar * sin(FTx^);
  FTy^ := vvar * sin(FTy^);
  FTz^ := vvar * sin(FTz^);  // AV: changed from linear scale
{$else}  
asm    // AV: added inline asm code
    fld     qword ptr [eax + vvar]
    mov     edx, [eax + FTx]
    fld     qword ptr [edx]      // FTx
    fsin
    fmul    st, st(1)
    fstp    qword ptr [edx]

    fld     qword ptr [edx + 8]  // FTy
    fsin
    fmul    st, st(1)
    fstp    qword ptr [edx + 8]

    fld    qword ptr [edx + 32] // FTz
    fsin
    fmulp
    fstp    qword ptr [edx + 32]

    fwait
{$endif}  
end;

///////////////////////////////////////////////////////////////////////////////
constructor TVariationPreSinusoidal.Create;
begin
	use3D := 0;
end;

///////////////////////////////////////////////////////////////////////////////
class function TVariationPreSinusoidal.GetInstance: TBaseVariation;
begin
  Result := TVariationPreSinusoidal.Create;
end;

///////////////////////////////////////////////////////////////////////////////
class function TVariationPreSinusoidal.GetName: string;
begin
  Result := 'pre_sinusoidal';
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationPreSinusoidal.GetVariableNameAt(const Index: integer): string;
begin
  case Index of
  0: Result := 'pre_sinusoidal_use3D';
  else
    Result := '';
  end;
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationPreSinusoidal.SetVariable(const Name: string; var value: double): boolean;
begin
  Result := False;
  if Name = 'pre_sinusoidal_use3D' then begin
    if (Value > 1) then Value := 1;
    if (Value < 0) then Value := 0;
    use3D := Round(Value);
    Result := True;
  end;
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationPreSinusoidal.GetNrVariables: integer;
begin
  Result := 1;
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationPreSinusoidal.GetVariable(const Name: string; var value: double): boolean;
begin
  Result := False;
  if Name = 'pre_sinusoidal_use3D' then begin
    Value := use3D;
    Result := True;
  end;
end;

///////////////////////////////////////////////////////////////////////////////
initialization
  RegisterVariation(TVariationClassLoader.Create(TVariationPreSinusoidal), true, false);
end.
