{
     Apophysis Copyright (C) 2001-2004 Mark Townsend
     Apophysis Copyright (C) 2005-2006 Ronald Hordijk, Piotr Borys, Peter Sdobnov
     Apophysis Copyright (C) 2007-2008 Piotr Borys, Peter Sdobnov
     
     Apophysis "3D hack" Copyright (C) 2007-2008 Peter Sdobnov
     Apophysis "7X" Copyright (C) 2009-2010 Georg Kiehne
     Apophysis AV "Phoenix Edition" Copyright (C) 2021 Alice V. Koryagina

     This program is free software; you can redistribute it and/or modify
     it under the terms of the GNU General Public License as published by
     the Free Software Foundation; either version 2 of the License, or
     (at your option) any later version.

     This program is distributed in the hope that it will be useful,
     but WITHOUT ANY WARRANTY; without even the implied warranty of
     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
     GNU General Public License for more details.

     You should have received a copy of the GNU General Public License
     along with this program; if not, write to the Free Software
     Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
}

unit varHypertile3D1;

interface

uses
  BaseVariation, XFormMan;

type
  TVariationHypertile3D1 = class(TBaseVariation)
  private
    hypertile3D1_p, hypertile3D1_q: integer;
	pa, r, c2, s2z: double;
  public
    constructor Create;

    class function GetName: string; override;
    class function GetInstance: TBaseVariation; override;

    function GetNrVariables: integer; override;
    function GetVariableNameAt(const Index: integer): string; override;

    function SetVariable(const Name: string; var value: double): boolean; override;
    function GetVariable(const Name: string; var value: double): boolean; override;
    function ResetVariable(const Name: string): boolean; override;

	  procedure Prepare; override;
    procedure CalcFunction; override;
  end;

implementation

uses
  Math;

///////////////////////////////////////////////////////////////////////////////
procedure TVariationHypertile3D1.Prepare;
var 	
	t, qa: double;
begin
	pa := PI2 / hypertile3D1_p;
	qa := PI2 / hypertile3D1_q;
	t := cos(pa);
	r := -(t - 1) / (t + cos(qa));
	if (r > 0) then
        r := 1 / sqrt(1 + r)
    else
        r := 1;

	c2 := sqr(r);
	s2z := 1 - c2;
end;

procedure TVariationHypertile3D1.CalcFunction;
var 	
	sina, cosa, cx, cy, s2x, s2y, x2cx, y2cy, r2, vr: double;
begin
  SinCos(random(32767) * pa, sina, cosa);
  cx := r * cosa;
  cy := r * sina; 
  s2x := 1 + sqr(cx) - sqr(cy);
  s2y := 1 + sqr(cy) - sqr(cx);

  r2 := sqr(FTx^) + sqr(FTy^) + sqr(FTz^);
  
  x2cx := 2 * cx * FTx^;
  y2cy := 2 * cy * FTy^;

  vr := vvar / (c2 * r2 + x2cx - y2cy + 1); 

  FPx^ := FPx^ + vr * (FTx^ * s2x - cx * ( y2cy - r2 - 1));
  FPy^ := FPy^ + vr * (FTy^ * s2y + cy * (-x2cx - r2 - 1));
  FPz^ := FPz^ + vr * (FTz^ * s2z);
end;

///////////////////////////////////////////////////////////////////////////////
constructor TVariationHypertile3D1.Create;
begin
  hypertile3D1_p := 3; 
  hypertile3D1_q := 7;
end;

///////////////////////////////////////////////////////////////////////////////
class function TVariationHypertile3D1.GetInstance: TBaseVariation;
begin
  Result := TVariationHypertile3D1.Create;
end;

///////////////////////////////////////////////////////////////////////////////
class function TVariationHypertile3D1.GetName: string;
begin
  Result := 'hypertile3D1';
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationHypertile3D1.GetVariableNameAt(const Index: integer): string;
begin
  case Index Of
  0: Result := 'hypertile3D1_p';
  1: Result := 'hypertile3D1_q';
  else
    Result := '';
  end
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationHypertile3D1.SetVariable(const Name: string; var value: double): boolean;
begin
  Result := False;
  if Name = 'hypertile3D1_p' then begin
    if Value < 3 then Value := 3;
	hypertile3D1_p := Round(Value);
    Result := True;
  end else if Name = 'hypertile3D1_q' then begin
    if Value < 3 then Value := 3;
    hypertile3D1_q := Round(Value);
    Result := True;
  end;
end;

function TVariationHypertile3D1.ResetVariable(const Name: string): boolean;
begin
  Result := False;
  if Name = 'hypertile3D1_p' then begin
    hypertile3D1_p := 3;
    Result := True;
  end else if Name = 'hypertile3D1_q' then begin
    hypertile3D1_q := 7;
    Result := True;
  end;
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationHypertile3D1.GetNrVariables: integer;
begin
  Result := 2;
end;

///////////////////////////////////////////////////////////////////////////////
function TVariationHypertile3D1.GetVariable(const Name: string; var value: double): boolean;
begin
  Result := False;
  if Name = 'hypertile3D1_p' then begin
    Value := hypertile3D1_p;
    Result := True;
  end else if Name = 'hypertile3D1_q' then begin
    Value := hypertile3D1_q;
    Result := True;
  end;
end;

///////////////////////////////////////////////////////////////////////////////
initialization
  RegisterVariation(TVariationClassLoader.Create(TVariationHypertile3D1), true, false);
end.